home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 17 / CU Amiga Magazine's Super CD-ROM 17 (1997)(EMAP Images)(GB)[!][issue 1997-12].iso / CUCD / Programming / DiceSource / src / alib / csup / clib / rt.asm < prev    next >
Assembly Source File  |  1994-02-14  |  3KB  |  155 lines
  1.     section romhunks
  2. *
  3. *    68000 SUPPORT LIBRARY
  4. *    COPYRIGHT 1984 GREEN HILLS SOFTWARE
  5. *    MAY 28, 1984
  6. *    32 REMAINDER,DIVIDE, AND MULTIPLY PACKAGE
  7. *
  8. *    THIS PACKAGE IS DIVIDED INTO TWO PARTS.
  9. *    ALL REMAINDERS AND DIVIDES ARE DONE WITH ENTRY
  10. *    POINTS TO A 32 BIT DIVIDE/REMAINDER ROUTINE.
  11. *    THIS PACKAGE USES a0,a1,d0,d1,d2.
  12. *
  13. *    UNSIGNED AND SIGNED 32 BIT MULTIPLIES ARE IDENTICAL,
  14. *    AND ARE PERFORMED BY THE SAME ROUTINE. THIS ROUTINE
  15. *    USES d0,d1,d2, AND a0.
  16. *
  17. *    32 BIT REMAINDER AND DIVIDE ROUTINE
  18. *    PARAMETERS IN d1 AND d2
  19. *    THIS PACKAGE HAS BEEN TESTED ON 5000 RANDOM NUMBER
  20. *    PAIRS AGAINST THE VAX. THE NUMBER GENERATION SCHEME
  21. *    GENERATED NUMBERS OF SIZE 1-32 BITS RANDOMLY, AND SHOULD
  22. *    THEREFORE HAVE EXERCISED MOST CODE PATHS.
  23. *
  24. *    COMMENTS AND SUGGESTIONS FOR IMPROVEMENTS ARE WELCOME.
  25. POSDIV:
  26.     cmpi.l    #$0FFFF,d2    *DIVISOR MORE THAN 16 BITS OF SIGNIF?
  27.     bgt.s    LONGDIV        *YES, GOTO ITERATION DIVIDE
  28.     move.w    d1,a1        *STANDARD 32/16 DIVIDE WITHOUT LOSS
  29.     clr.w    d1
  30.     swap    d1
  31.     divu    d2,d1
  32.     move.l    d1,d0
  33.     swap    d1
  34.     move.w    a1,d0
  35.     divu    d2,d0
  36.     move.w    d0,d1
  37.     clr.w    d0
  38.     swap    d0
  39.     rts
  40. LONGDIV:
  41.     move.l    d1,d0
  42.     clr.w    d0
  43.     swap    d0
  44.     swap    d1
  45.     clr.w    d1
  46.     move.l    d2,a1
  47.     moveq    #$0F,d2
  48. LABEL1:    add.l    d1,d1        *BEGIN DIVIDE BY ITERATION
  49.     addx.l    d0,d0
  50.     cmp.l    d0,a1
  51.     bgt.s    LDEX
  52.     sub.l    a1,d0
  53.     addq.w    #1,d1
  54. LDEX:    dbf    d2,LABEL1
  55.     rts
  56. *
  57. * lmul, ulmul
  58. * 32 BIT MULTIPLY ROUTINES
  59. * 
  60.     xdef    lmult
  61.     xdef    ulmult
  62. lmult:
  63. ulmult:
  64.     move.l    d2,-(sp)    *SAVE d2 REGISTER
  65.     move.l    d0,d2
  66.     mulu    d1,d2
  67.     move.l    d2,a0
  68.     move.l    d0,d2
  69.     swap    d2
  70.     mulu    d1,d2
  71.     swap    d1
  72.     mulu    d1,d0
  73.     add.l    d2,d0
  74.     swap    d0
  75.     clr.w    d0
  76.     add.l    d0,a0
  77.     move.l    a0,d0
  78.     move.l    (sp)+,d2
  79.     rts
  80. *
  81. *    ulmodt
  82. *    UNSIGNED 32 BIT REMAINDER 
  83.     xdef    ulmodt
  84. ulmodt:    move.l    d2,-(sp)        *SAVE d2
  85.     move.l    d1,d2    *SETUP PARAMETERS
  86.     move.l    d0,d1
  87.     bsr.s    POSDIV        *CALL UNSIGNED DIV/REM ROUTINE
  88.     move.l    (sp)+,d2        *RESTORE d2
  89.     rts
  90. *
  91. *    uldiv
  92. *    UNSIGNED 32 BIT DIVIDE
  93.     xdef    uldivt
  94. uldivt:
  95.     move.l    d2,-(sp)        *SAVE d2 AND d3
  96.     move.l    d1,d2
  97.     move.l    d0,d1    *LOAD UP PARAMETERS
  98.     bsr    POSDIV
  99.     move.l    d1,d0
  100.     move.l    (sp)+,d2
  101.     rts
  102. *
  103. *    lrem
  104. *    SIGNED 32 BIT REMAINDER
  105. *    IF DIVISOR IS NEGATIVE, RESULT IS NEGATIVE.
  106.     xdef    lmodt
  107. lmodt:
  108.     move.l    d2,-(sp)    *SAVE d2
  109.     move.l    d1,d2
  110.     bge.s    lrem1
  111.     neg.l    d2
  112. lrem1:
  113.     move.l    d0,d1
  114.     moveq    #0,d0        *NEGATION FLAG OFF
  115.     tst.l    d1
  116.     bge.s    lrem2
  117.     neg.l    d1
  118.     not.l    d0        *NEGATION FLAG ON
  119. lrem2:    move.l    d0,a0        *MOVE FLAG TO A SAFE PLACE
  120.     bsr    POSDIV
  121.     move.w    a0,d2
  122.     beq.s    lremDONE
  123.     neg.l    d0
  124. lremDONE:    move.l (sp)+,d2        *RESTORE d2 
  125.     rts
  126. *
  127. *    ldivt    
  128. *    SIGNED 32 BIT DIVIDE
  129. *    IF DIVIDEND XOR DIVISOR IS NEGATIVE,
  130. *    RESULT MUST BE NEGATIVE.
  131.     xdef    ldivt
  132. ldivt:
  133.     move.l    d2,-(sp)
  134.     move.l    d0,a0
  135.     moveq    #0,d0
  136.     move.l    d1,d2
  137.     bge.s    ldiv1
  138.     neg.l    d2        *NEGATE OPERAND
  139.     not.l    d0
  140. ldiv1:    move.l    a0,d1
  141.     bge.s    ldiv2
  142.     neg.l    d1        *NEGATE OPERAND
  143.     not.l    d0
  144. ldiv2:    move.l    d0,a0        *TUCK AWAY NEGATION FLAG
  145.     bsr    POSDIV
  146.     move.l    a0,d2
  147.     beq.s    ldivRET
  148.     neg.l    d1
  149. ldivRET:    move.l    d1,d0
  150.     move.l    (sp)+,d2
  151.     rts
  152.  
  153.     end
  154.  
  155.